Hatena::Grouphokudaisicp

TSBの日記

 | 

2009-01-05

2.3.2

18:22

;;p86-p87
(define (variable? x) (symbol? x))
(define (same-variable? v1 v2)
	(and (variable? v1) (variable? v2) (eq? v1 v2)))
(define (make-sum a1 a2) (list '+ a1 a2))
(define (make-product m1 m2) (list '* m1 m2))
(define (sum? x) (and (pair? x) (eq? (car x) '+)))
(define (addend s) (cadr s))
(define (augend s) (caddr s))
(define (product? x) (and (pair? x) (eq? (car x) '*)))
(define (multiplier p) (cadr p))
(define (multiplicand p) (caddr p))
;;p87-p88
(define (make-sum a1 a2)
	(cond ((=number? a1 0) a2)
		((=number? a2 0) a1)
		((and (number? a1) (number? a2)) (+ a1 a2))
		(else (list '+ a1 a2))))
(define (=number? exp num)
	(and (number? exp) (= exp num)))
(define (make-product m1 m2)
	(cond ((or (=number? m1 0) (=number? m2 0)) 0)
		((=number? m1 1) m2)
		((=number? m2 1) m1)
		((and (number? m1) (number? m2)) (* m1 m2))
		(else (list '* m1 m2))))
;;p86 DERIV
(define (deriv exp var)
	(cond ((number? exp) 0)
		((variable? exp)
		(if (same-variable? exp var) 1 0))
		((sum? exp)
		(make-sum (deriv (addend exp) var)
			(deriv (augend exp) var)))
		((product? exp)
		(make-sum
			(make-product (multiplier exp)
					(deriv (multiplicand exp) var))
			(make-product (deriv (multiplier exp) var)
					(multiplicand exp))))
		(else
			(error "unknown expression type -- DERIV" exp))))
;;check
(print (deriv '(+ x 3) 'x))
(print (deriv '(* x y) 'x))
(print (deriv '(* (* x y) (+ x 3)) 'x))

;;ANS1
;;(+ 1 0)
;;(+ (* x 0) (* 1 y))
;;(+ (* (* x y) (+ 1 0)) (* (+ (* x 0) (* 1 y)) (+ x 3)))

;;ANS2
;;1
;;y
;;(+ (* x y) (* y (+ x 3)))

;;problem 2.56
(define (exponentiation? x)
  (and (pair? x) (eq? (car x) '**)))
(define (base s) (cadr s))
(define (exponent s) (caddr s))
(define (make-exponentiation b exp)
  (cond ((=number? exp 0) 1) ;何かの0乗は1
        ((=number? exp 1) b) ;何かの1乗はそれ自身
        (else (list '** b exp))))

(define (deriv exp var)
  (cond ((number? exp) 0)
        ((variable? exp)
         (if (same-variable? exp var) 1 0))
        ((sum? exp)
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((product? exp)
         (make-sum
          (make-product (multiplier exp)
                        (deriv (multiplicand exp) var))
          (make-product (deriv (multiplier exp) var)
                        (multiplicand exp))))
        ;;ここから追加
        ((exponentiation? exp)
         (make-product
          (make-product (exponent exp)
                        (make-exponentiation (base exp) (- (exponent exp) 1)))
          (deriv (base exp) var)))
        ;;ここまで
        (else
         (error "unknown expression type -- DERIV" exp))))
;;check
(print (deriv '(** (+ x 1) 5) 'x))
(print (deriv '(** (+ (* x 4) 3) 5) 'x))
;;ANS - 2.56
;;(* 5 (** (+ x 1) 4))
;;(* (* 5 (** (+ (* x 4) 3) 4)) 4)

参考:http://sicp.naochan.com/memo.pl?p=%A1%D4%CB%DC%B2%C8%A1%D5%C1%C7%BF%CD%A4%AF%A4%B5%A4%A4SICP%C6%C9%BD%F1%B2%F1

 |